* Test fuer Triodenmodell
*******************
*SRC=12AU7A2;12AU7A2;Tubes;Complex;Triode, No Heater
*SYM=TRIODE1
.SUBCKT 12AU7A2   1     2      3   
*                Anode Grid Cathode  
* COPYRIGHT EXCEM, 1993 Triode without Heater Model
*
X1 1 2 3  TRIODE1 

* {ISAT=99m SFS=0.7 VBIG=-0.9 VBIA=-1.3 MU=17 RMU=0.5 VMU=-20 SFMU=1.6 
* + K=827E-6 RK=0.08 VK=-20 SFK=1.6 SIGMAG=0.05 ALPHAG=5.2 SFG=3.5}
*
*
*
C2 1 2 1.5P
C3 3 1 0.5P
C4 2 3 1.6P 
*
*
*INCLUDE VACUUMNL.LIB
.ENDS
*
*
*
*
.SUBCKT TRIODE1  A G C  PARAMS: K=827E-6 RK=0.08 VK=-20 SFK=1.6 MU=19.5 RMU=0.5 VMU=-20 SFMU=1.6 VBIG=-0.9 VBIA=-1.3 ISAT=99m SFS=0.7 ALPHAG=5.2 SIGMAG=0.05 SFG=3.5
*
* THE TRIODE'S 14 PARAMETERS ARE:
*
*     SFS     shape factor of the saturation law.
*     VBIG    contact potential of the grid
*             (the voltage above which grid may current start to flow).
*     VBIA    contact potential of the anode.
*     MU      amplification factor at slighly negative grid voltage.
*     RMU     reduction factor for MU at very negative grid voltage.
*     VMU     grid voltage for mid-range MU (negative).
*     SFMU    shape factor for MU reduction law. 
*     K       perveance at slightly negative grid voltage.
*     RK      perveance reduction factor at very negative grid voltage.
*     VK      grid voltage for mid-range perveance (negative).
*     SFK     shape factor for perveance reduction law. 
*     SIGMAG  effective cross-section of the grid relative to the anode.
*     ALPHAG  grid current amplification factor.
*     SFG     shape factor of the grid current law.
* H ist ein Hilfsknoten zum Test der Gl. kann später wieder entfernt werden
**********V = V(G,C) < -1P ?
B31 30 0 V = V(G,C)  / {VK}
*
B1 15 0 V = U(1P-V(G,C))*({K} * (1+{RK} * (V(30))^{SFK}) / (1 + (V(30))^{SFK})) + U(V(G,C)-1P) * {K}
* V(15) is the effective perveance 
*
**********V = V(G,C) < -1P ?
*
B32 31 0 V = (V(G,C))/{VMU}
B2 16 0 V=U(1P-V(G,C))* ( {MU}*(1 + {RMU}*(V(31))^{SFMU}) /(1 + (V(31))^{SFMU})) + U(V(G,C)-1P) *{MU}
*
*
*
*
* V(16) is the effective MU
*
B4 9 0 V = V(G,C) - {VBIG} + (V(A,C) - {VBIA}) / (V(16) + 1)
*
***********V(9) > 0 ?
B6 10 0 V = U(V(9))* V(15) * V(9)^1.5 / ({ISAT} + 1P)
*
**********V(10) < {SFS} ?
B7 12 0 V = U({SFS} - V(10)) * V(10) * ({ISAT} + 1P) + U(V(10)-{SFS})*({ISAT} + 1P) * ({SFS} + (V(10) - {SFS}) * {1-SFS} / ({1 - 2 * SFS} + V(10)))
*
* B7 contains an arbitrary saturation law modeled by the shape factor SFS
* to match the available data. SFS should be between 0 and 1. The
* lower SFS the sloppier the saturation law.
*
*
*********V(A,C) > {VBIA + 0.1M} ?
B8 14 0 V =  U(V(A,C)-{VBIA}-0.1m)*((V(A,C) - {VBIA}) / {ALPHAG}) + U(-V(A,C)+{VBIA}+0.1m)*2P
*
**********V(G,C) > {VBIG + 0.1M} ?V(14) > 1P ?
B9 28 0  V = U(V(G,C)-{VBIG+0.1m})*U(V(14)-1p)*((V(G,C)-{VBIG} + {SIGMAG^(1/SFG)}*V(14))/(V(G,C)-{VBIG} + V(14)))^{SFG}
*
*
*
*
B10 8 0 V = U(-V(G,C))* V(28) * (({VBIG+10U} + V(C) - V(G)) / {VBIG+10U}) + U(V(G,C))*V(28)
*
B15 G C I = V(8) * V(12)
*
B17 A C I = (1 - V(8)) * V(12)
*
*
.ENDS